Text.DocTemplates

A simple templating system with variable substitution and conditionals. This module was formerly part of pandoc and is used for pandoc's templates. The following program illustrates its use:

import Data.Text
import Data.Aeson
import Text.DocTemplates

data Employee = Employee { firstName :: String
                         , lastName  :: String
                         , salary    :: Maybe Int }
instance ToJSON Employee where
  toJSON e = object [ "name" .= object [ "first" .= firstName e
                                       , "last"  .= lastName e ]
                    , "salary" .= salary e ]

template :: Text
template = "$for(employee)$Hi, $employee.name.first$. $if(employee.salary)$You make $employee.salary$.$else$No salary data.$endif$$sep$\n$endfor$"

main = case compileTemplate template of
         Left e    -> error e
         Right t   -> putStrLn $ renderTemplate t $ object
                        ["employee" .=
                          [ Employee "John" "Doe" Nothing
                          , Employee "Omar" "Smith" (Just 30000)
                          , Employee "Sara" "Chen" (Just 60000) ]
                        ]

A slot for an interpolated variable is a variable name surrounded by dollar signs. To include a literal $ in your template, use $$. Variable names must begin with a letter and can contain letters, numbers, _, -, and ..

The values of variables are determined by a JSON object that is passed as a parameter to renderTemplate. So, for example, title will return the value of the title field, and employee.salary will return the value of the salary field of the object that is the value of the employee field.

The value of a variable will be indented to the same level as the variable.

A conditional begins with $if(variable_name)$ and ends with $endif$. It may optionally contain an $else$ section. The if section is used if variable_name has a non-null value, otherwise the else section is used.

Conditional keywords should not be indented, or unexpected spacing problems may occur.

The $for$ keyword can be used to iterate over an array. If the value of the associated variable is not an array, a single iteration will be performed on its value.

You may optionally specify separators using $sep$, as in the example above.

Documentation

renderTemplate :: (ToJSON a, TemplateTarget b) => Template -> a -> b

Render a compiled template using context to resolve variables.

applyTemplate :: (ToJSON a, TemplateTarget b) => Text -> a -> Either String b

Combines renderTemplate and compileTemplate.

class TemplateTarget a where

Minimal complete definition

toTarget

Methods

toTarget :: Text -> a

Instances

TemplateTarget ByteString

Methods

toTarget :: Text -> ByteString

TemplateTarget String

Methods

toTarget :: Text -> String

TemplateTarget Text

Methods

toTarget :: Text -> Text

TemplateTarget Html

Methods

toTarget :: Text -> Html

varListToJSON :: [(String, String)] -> Value

A convenience function for passing in an association list of string values instead of a JSON Value.

compileTemplate :: Text -> Either String Template

Compile a template.

data Template

A Template is essentially a function that takes a JSON Value and produces Text.

Instances

Monoid Template

Methods

mempty :: Template

mappend :: Template -> Template -> Template

mconcat :: [Template] -> Template